Simple code inquiry

ah so that's what clone does, thanks Nic very helpful!

Hi mo13 ,

To change a CC to a toggle, you need to trap when the CC goes ON and alternate between rewriting to ON and OFF each time. This code will do it:

if load
 # CC channel + number to toggle
 assign K0 = B0 $127
 # toggle flag (ON to start)
 assign L0 = 7F
end

# trap toggle CC
if M0 = K0 K1
 if M2 == 7F
   # send toggle version of CC if ON
   send K0 K1 L0
   calc L0 = L0 ^ 7F
 end
 block
end

Regards, Nic.

I'd just like to point out that the last 8 CC#s (120-127) are special Channel Mode commands with pre-defined meanings. They're meant to control the way the channel works. CC 127 turns out to be Poly Mode On. So it would be better to avoid them, in case some component grabs them instead of passing them on as normal CCs. Just sayin'.

This should do the trick:
#ToggleCCs

If load
Alias 77 maxCC # higher CCs are channel controls

# toggle memories, initialized to OFF.
# +P means they are saved with any host preset.
Ass L00 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass L10 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass L20 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass L30 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass L40 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass L50 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass L60 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass L70 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass L80 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass L90 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass LA0 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass LB0 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass LC0 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass LD0 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass LE0 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 +P
Ass LF0 = 0 0 0 0 0 0 0 0 +P
End # Initialization ———————————————————————————

# process all CC on ch. 3. Message ch. is one less.
If M0 == B2
 If M1 <= maxCC # only modify valid CC
   If M2 == 7F # process button press
     Mat LM1 = LM1 ^ 7F # toggle saved value
     Ass M2 = LM1 # replace message value
   Else
     Block # ignore release
   End
 End
End

Of course. Make sure you expand the initialization of LF0 to 16 zeros, and change maxCC to 7F.

You're still passing the message through as a CC. If I understand correctly, you want a CC ON value on MIDI channel 3 to toggle the saved value, and transmit Note On if the value is set, and Note Off if the value is clear. The output channel is 3 and the note number matches the CC#. This ought to work:
If M0 == B2
 If M1 <= 7F
   If M2 == 7F
     Mat LM1 = LM1 ^ 7F
     Ass M2 = LM1
     If M2 == 7F
         Ass M0 = 92
     Else
         Ass M0 = 82
     End
   Else
     Block
   End
  End
End
Leave the initialization unchanged and replace the logic block with this. Just for reference, M0 holds the message type and channel, M1 holds the CC# or note #, M2 holds the CC value or note velocity. The interpretations of M1 and M2 depend on the message type. When we use LM1, we're accessing position number M1 in the L data array. This is called an indexed or indirect array reference in other languages. It lets us remember the state of all 127 toggles, and easily select the one corresponding to the CC#. And by the way, each message enters SB, is broken up into the M array, we modify the values in M, and SB sends it on. SB does all this automatically, so all we need to provide is the logic to modify the values.