LED Feedback help

Here's my suggested update to your code. What you had wrong was the subroutine parameters. The parameters are the additional names, like "theFirst" that appear on the Sub line after the subroutine name. They are used inside the Sub like variables. They are passed to the Sub where it is called. They let the same Sub do different stuff at different times; quite a powerful concept. You used Aliases which turned them into constants, which is not desired.

Also, I guess you know that the code in If Load is just run when the script is loaded, and the Subs are not even run, they are just prepared. You need events from outside to trigger pieces of code outside If Load to do any work. In my update of your code, I use Note events to test the script. You probably already have CCs or other events to do this.

I suggest that you load this script, just like it is. Send in some notes and watch a MIDI monitor. The first note will clear all the LEDs and set one. Every following note will clear the previous LED and set another.

#LEDFeedback

If load
 Alias 0 firstCC
 Alias $31 lastCC
 Alias J00 oldValue   # this is the CC# previously lit
 Alias I00 reg0
 Alias B2 sendCC #feedback ch.

 Mat oldValue = lastCC + 1    # impossible value indicates first time

 # sends zero to all CCs in the range. Used by SetLed.
 # theFirst and theLast are parameters, not constants. They come
 # from the subroutine call.
 Sub ClearBlock theFirst theLast
    Ass reg0 = theFirst
    While reg0 <= theLast
       Snd sendCC reg0 3 #value that clears out the LED"s
       Mat reg0 = reg0 + 1
    End
 End

  # you need to call this with the LED # you want to light, and the color,
  # maybe
  #    SetLed 7 5
  # to light LED 7 with color 5.
  # You would do this from an event in the lower part of the script (outside
  # If load), or from a Sub lower down in If load.
 Sub SetLed theCC theColor
    If oldValue > lastCC     # first time clears all
       ClearBlock firstCC lastCC
    Else
         # should this send 0 or 3 to turn light off?
       Snd sendCC oldValue 3      # normal turns off previous
    End
    Ass oldValue = theCC      # remember the CC
    Snd sendCC theCC theColor      # and turn it on
 End

End # Initialization ———————————————————————————

# sample test code. Lights one light based on incoming note.
If MT == 90
  # reduce note # to 0..31
  Mat I10 = M1 % $32
  SetLed I10 5
End
# block the test note messages
If MT < A0
  Block
End

There is no feedback in my script or yours. You need to add that code after my note event handler. Code that responds to whatever comes in, CCs, whatever, and calls SetLed with the proper CC# and color. There is no magic here. The subroutines do the work, but but you need event handlers to trigger them. What event is supposed to trigger this feedback? Is it the same CC# on MIDI channel 1? That would just be:
If M0 == B0    # CC on ch. 1
  If M1 <= lastCC   # one of first 32 CCs
     SetLed M1 5
  End
End
That will set the led corresponding to the CC#, if it's less than 32. It does not block the CC, but you could add that.

Note that these event handlers are outside the If Load section. They are run (once) for every MIDI message entering the block. The If logic identifies what kind of message it is and takes appropriate action. And, unless you Block them, the incoming messages all flow out of SB to whatever it is connected to.

Yes. It might be easiest for you to make a new SetLed for each bank, using different start/end constants, and a different variable for the oldValue. Create new aliases for the limits, and for the oldValue. You can just use J01 etc. for the new saved values. And you'll need to change the event logic so it selects the correct Sub based on the input CC#.

You're still confusing Sub parameters with defined variable names (Aliases). You should leave the Subs with parameters theCC and theColor, as I wrote it. Those parameter names should appear only on the Sub line and inside the Sub. They are replaced with the variables from the place where the Sub is called. The call is where the Sub name appears without Sub in front of it. Study my version to see the Sub definition, with its parameters, used inside the Sub (before its End), and the call, where variables are passed to the Sub. Notice that the CC# (M1) and the color (5 or 6) in the call of SetLed are passed to theCC and theColor in the Sub. This lets the Sub do different stuff each time.

You need better logic to separate the second bank CCs. Like
If M1 >= firstCC-B
  If M1 <= lastCC-B
     SetLed-B M1 6
  End
End
Your version does both actions for buttons in the first bank, since M1 is <= both limits.

Also, I would not have used a dash ("-") in these names, because it is also a minus sign. It appears to work, but the normal convention would be to simply attach the extra letter, or use underscore ("_") between them.

OK. This is good, I think. Now we can think about the next steps. I've written the programmer version of this, with some (I hope) helpful info.

A StreamByter script is actually a computer program, and in order to understand it, you have to think like a programmer. This is basically second nature to me because I've done it for so long. But, you need to be able to look at a line of code and know exactly what it does, and why it is where it is. To help you with this, I've written the script that handles all 4 banks of 32 LEDs. I've tested this, and it manages each bank as a separate set of 32 LEDs, setting only one at a time.

The script is written as a tutorial. I've purposely left out any comments, and most of the Aliases that make the code more readable. I've replaced them with a lot of questions, which you should try to answer. Look up the items in the SB manual, so you have a clearer idea of what they do, and why they are useful. You may need to skip some of the questions at first, because they depend on items farther down the code. It may be helpful to download the PDF version of the SB manual for easier reading. I use mine almost every day, to check on various peculiarities.

If you post the answers to the questions, and ask for explanation of parts that are unclear, I'll review them and try to give explanations. You could PM the answers, if you don't want to post them.

#SetLedAny
# This script handles 4 separate banks of 32 LEDs.
# Please try it out, and try to answer all the questions.
# You need to read the manual to answer some of them.
# And you need to finish reading the program before you
# can answer some of them.

If load
# 1a. When does this part run? How often?
# 1b. Where does this part end?

Alias $32 bankSize
Alias 4 numBanks
Alias B2 setCommand
Alias $112  totalBanks
# 2a. Why do we use Alias for these values?
# 2b. What happens when we use the Alias name in the script?
# 2c. How many LEDs are in a bank?

Ass J00 = 80 80 80 80
# 3a. Which variables does this initialize? List them.
# 3b. What is Jii used for? Hint: look in SetLedAny.
# 3c. Why do we use 80 here? Hint: what CC#s are possible?

Ass K00 = 5  6  4  6   3  0  3  0
# 4a. Which variables does this initialize? List them.
# 4b. What is Kii used for? Hint: look in SetLedAny.
# 4c. How can we change the color used in a given bank?
# 4d. How can we change the background color for a bank?

Sub ClearBank pBank
  # 5a. What is ClearBank?
  # 5b. When does it run?
  # 5c. What is pBank?
  # 5d. pBank is never assigned, so how does it get a value?
  Mat I20 = pBank * bankSize
  # 6a. What is I20?
  # 6b. What value is I20 when pBank is 0, 1, 2, or 3?
  Mat I21 = I20 + bankSize
  # 7a. What value is I21?
  If I21 > totalBanks
     Ass I21 = totalBanks
  End
  # 29a. What value is I21 now?
  # 29b. What happens to LEDs 112-127?
  Mat I22 = pBank + numBanks
  Ass I22 = KI22
  # 30a. What value is I22 now?

  # 8a. What does the While do?
  # 8b. What values does I20 go through before the loop stops?
  While I20 < I21
     Send setCommand I20 I22
     # 9a. What MIDI message does this send for each value of I20?
     # 9b. What color does it use?
     Mat I20 = I20 + 1
     # 10a. How does I20 change here?
     # 10b. How does this affect the While?
  End
End

# 11a. What does ClearBank do when it is called?
# 11b. (Extra Credit) Why use a separate Sub for ClearBank?
# Couldn't we just put it inside SetLedAny?

Sub SetLedAny pNumb
  # 12a. What is SetLedAny?
  # 12b. When does it run?
  # 12c. What is pNumb?
  # 12d. pNumb is never assigned, so how does it get a value?
  Mat I10 = pNumb / bankSize
  # 13a. What value does I10 get? Consider different CC#s from 0 to 127.
  # Remember that integer divide truncates. No decimal part.

  # 14a. What is JI10? What value does it have?
  # 14b. What does it mean when JI10 is 80?
  If JI10 == 80
     ClearBank I10
     # 15a. What does ClearBank I10 do?
  Else
     # 17a. When do we execute this and not ClearBank?
     Mat I11 = I10 + numBanks
     Send setCommand JI10 KI11
     # 16a. What MIDI message does this send?
     # 16b. Which LED does it clear?
     # 16c. What color does it clear the LED to?
  End

  Send setCommand pNumb KI10
  # 18a. What MIDI message does this send?
  # 18b. Which LED does it set?
  # 18c. What color does it use?
  Ass JI10 = pNumb
  # 19a. What value does JI10 get here?
  # 19b. How will that affect the next call for this bank?
End

# 20a. What does SetLedAny do when it is called?
# 20b. What happens the first time SetLedAny is called for a bank?
# 20c. What happens on every other call for a bank?

# 25a. (Extra Credit) Why did I use I10 in one Sub, I20 in the other? Why not just use I10 everywhere?

Set Name SetLed
# 21a. What is the Name?
# 21b. Why is it useful?

End # Initialization ———————————————————————————

# 22a. What is this part of the script? Hint: it handles events.
# 22b. When does it run? How often?
# 22c. What values are in M0, M1, and M2 when it runs?
# 22d. What happens for a CC message on MIDI channel 3?
# 22e. What happens for any other message?

If M0 == B2
  # 27a. When does this part run?
  If M1 <  totalBanks
     # 28a. What happens on press of button 112?
     SetLedAny M1
     # 23a. What does SetLedAny M1 do?
     # 23b. What value is passed as pNumb in SetLedAny?
     # 26a. (Extra Credit) Why do I only call a Sub in the CC event handler?
     # Why not just put all the code right here?
  Else
     # can handle last 2 rows of 8 here
  End
End

# 24a. Do any MIDI messages leave this script? Which ones?
Block

I know this looks really long, but it's actually quite short, when the questions are removed. I've used the colors from your example, and I've blocked off CCs 112-127, so they can be handled differently.

Edit: Changed the background colors. Limited the last block to CC 111.

My version already has the different background colors. Just tell me how it works and I'll show you how to handle the toggles. (Hint: we use an array, same as I'm doing for the LED memories and bank colors.)

hey uncledave

this is on a separate SB instance but it still somehow clashes, as in renders your script for the first 4 banks inactive:


#toggles for last 2 banks

If load

Set Name SetToggles
 
# sets the initial state of Bank E and F LEDs
 
 Snd B2 70 03
 Snd B2 71 03
 Snd B2 72 03
 Snd B2 73 03
 Snd B2 74 03
 Snd B2 75 03
 Snd B2 76 03
 Snd B2 77 03
 Snd B2 78 02
 Snd B2 79 02
 Snd B2 7A 02
 Snd B2 7B 02
 Snd B2 7C 02
 Snd B2 7D 02
 Snd B2 7E 02
 Snd B2 7F 03
End

If M0 == B2
 If M1 <= 7F
   If M2 == 7F
     Mat LM1 = LM1 ^ 7F
     Ass M2 = LM1
     If M2 == 7F
       Ass M0 = 90
     Else
       Ass M0 = 80
     End
   Else
     Block
   End
 End
End

90 70-76 = B2 XX 05 +C # Bank E toggle
80 70-76 = B2 XX 03 +C
90 77-77 = B2 77 06 +C # Last CC Bank E
80 77-77 = B2 77 03 +C
90 78-7E = B2 XX 03 +C # Bank F toggle
80 78-7E = B2 XX 02 +C
90 7F-7F = B2 7F 05 +C # Last CC Bank F
80 7F-7F = B2 7F 03 +C

# [extra edit] ≈ Solos turn off the Mute LEDs correspondingly to AUM’s channels handled from another script.

90 70 = B2 78 03 +C
80 70 = B2 78 02 +C
90 71 = B2 79 03 +C
80 71 = B2 79 02 +C
90 72 = B2 7A 03 +C
80 72 = B2 7A 02 +C
90 73 = B2 7B 03 +C
80 73 = B2 7B 02 +C
90 74 = B2 7C 03 +C
80 74 = B2 7C 02 +C
90 75 = B2 7D 03 +C
80 75 = B2 7D 02 +C
90 76 = B2 7E 03 +C
80 76 = B2 7E 02 +C

XX = XX +B
[edit] I traced where the clash came from, there was an inactive script that somehow was still interfering with the rest.

Would you be so kind to point me in the right direction @how this can be incorporated with the 4 banks in the other script?