Convert + scale Pitch Bend to 3 CCs

mo13
Oracle

Posts: 146

Convert + scale Pitch Bend to 3 CCs Jun 17, 2024 17:00:56 GMT

Quote

Post by mo13 on Jun 17, 2024 17:00:56 GMT

I'm having a little trouble with converting and scaling Pitch Bend to 3 CC's to set a BPM on the other end which is 1-999

# Converting Pitch Bend on Ch.16 to 3 CCs (125, 126, 127)
# representing BPM values (1-999)

IF LOAD
  # Define constants for CC numbers
  ASS J0 = $125 # CC1 (125) - Hundreds digit
  ASS J1 = $126 # CC2 (126) - Tens digit
  ASS J2 = $127 # CC3 (127) - Ones digit
  
  # Initialize counters for digits
  ASS K0 = 0 0 0 0
  ASS L0 = 0
  ALIAS K0 HUNDREDS_DIGIT
  ALIAS K1 TENS_DIGIT
  ALIAS K2 ONES_DIGIT
  ALIAS K3 LAST_VALUE
  ALIAS L0 CURRENT_VALUE
  
  # Define loop boundaries
  ALIAS 0 MIN_LOOP
  ALIAS 9 MAX_LOOP
END

# Detect Pitch Bend message on Channel 16
IF M0 == EF
  # Calculate current pitch bend value (LSB + MSB * 128)
  MAT CURRENT_VALUE = M1 + M2 * 128
  
  # Determine direction of change
  IF CURRENT_VALUE > LAST_VALUE
    # Forward counting
    MAT ONES_DIGIT = ONES_DIGIT + 1
    
    # Check if ONES_DIGIT exceeds its range
    IF ONES_DIGIT > MAX_LOOP
      # Reset ONES_DIGIT to MIN_LOOP and increment TENS_DIGIT
      ASS ONES_DIGIT = MIN_LOOP
      MAT TENS_DIGIT = TENS_DIGIT + 1
    END
    
    # Check if TENS_DIGIT exceeds its range
    IF TENS_DIGIT > MAX_LOOP
      # Reset TENS_DIGIT to MIN_LOOP and increment HUNDREDS_DIGIT
      ASS TENS_DIGIT = MIN_LOOP
      MAT HUNDREDS_DIGIT = HUNDREDS_DIGIT + 1
    END
    
    # Check if HUNDREDS_DIGIT exceeds its range
    IF HUNDREDS_DIGIT > MAX_LOOP
      ASS HUNDREDS_DIGIT = MIN_LOOP
    END
  END
  
  IF CURRENT_VALUE < LAST_VALUE
    # Backward counting
    MAT ONES_DIGIT = ONES_DIGIT - 1
    
    # Check if ONES_DIGIT goes below its range
    IF ONES_DIGIT < MIN_LOOP
      # Set ONES_DIGIT to MAX_LOOP and decrement TENS_DIGIT
      ASS ONES_DIGIT = MAX_LOOP
      MAT TENS_DIGIT = TENS_DIGIT - 1
    END
    
    # Check if TENS_DIGIT goes below its range
    IF TENS_DIGIT < MIN_LOOP
      # Set TENS_DIGIT to MAX_LOOP and decrement HUNDREDS_DIGIT
      ASS TENS_DIGIT = MAX_LOOP
      MAT HUNDREDS_DIGIT = HUNDREDS_DIGIT - 1
    END
    
    # Check if HUNDREDS_DIGIT goes below its range
    IF HUNDREDS_DIGIT < MIN_LOOP
      ASS HUNDREDS_DIGIT = MAX_LOOP
    END
  END
  
  # Update LAST_VALUE with the current pitch bend value
  ASS LAST_VALUE = CURRENT_VALUE
  
  # Send CC messages with the BPM digits
  SND BF J0 HUNDREDS_DIGIT
  SND BF J1 TENS_DIGIT
  SND BF J2 ONES_DIGIT
  
END

# Specific handling for reset and preset values
IF M0 == EF 00 00
  # Reset all counters
  ASS HUNDREDS_DIGIT = 0
  ASS TENS_DIGIT = 0
  ASS ONES_DIGIT = 0
  ASS LAST_VALUE = 0
END

IF M0 == EF 01 00
  # Set counters to 0 0 1
  ASS HUNDREDS_DIGIT = 0
  ASS TENS_DIGIT = 0
  ASS ONES_DIGIT = 1
  ASS LAST_VALUE = 128 # Equivalent to EF 01 00 in pitch bend value
  # Send CC messages
  SND BF J0 0
  SND BF J1 0
  SND BF J2 1
END

IF M0 == EF 7E 7F
  # Set counters to 9 9 9
  ASS HUNDREDS_DIGIT = 9
  ASS TENS_DIGIT = 9
  ASS ONES_DIGIT = 9
  ASS LAST_VALUE = 16383 # Equivalent to EF 7E 7F in pitch bend value
END

Block

So I need the 3 outgoing CCs to correctly increment/decrement their values from 0 0 1 to 9 9 9 according tot the incoming PB.

EF 00 01 triggering to send out BF $125 00, BF $126 00, BF 127$ 01 , EF 7E 7F triggering BF $125 09, BF $126 09, BF 127$ 09
This is as close as I got but it's not incrementing/decrementing the values accordingly on the output, if anyone knows how else to possibly approach this?

Last Edit: Jun 17, 2024 22:40:07 GMT by mo13

redheronmusic
Oracle

Posts: 78

Convert + scale Pitch Bend to 3 CCs Jun 18, 2024 1:48:09 GMT

Quote

Post by redheronmusic on Jun 18, 2024 1:48:09 GMT

Sorry, not following the logic. But if you want to convert a hex number to individual decimal digits, this will do it. Before converting, we divide by 17 to scale 16383 to 999 (ish). But with the rounding, this maxes out at 963.

If Load
	Alias L0 Byte_2
	Alias L1 Byte_1
	Alias L2 Byte_0
	Alias L3 Total
	Alias L4 Remainder
End

If M0 == E0
	Mat Total = M1 * $128
	Mat Total = Total + M2
	Mat Total = Total / $17 # Scale 16383 / 999 = 16.39 (round to 17)

	Mat Byte_2 = Total / $100
	Mat Remainder = Total % $100

	Mat Byte_1 = Remainder / $10
	Mat Byte_0 = Remainder % $10

	Snd F0 58 58 Byte_2 Byte_1 Byte_0 F7 # Display result
End

We really need to divide by 16.39, but cannot do that directly in an integer system. So we cheat, multiply the total first by $100, then divide by $1639. The multiply exceeds scale of a 16 bit variable, so we move Total to the precision array (32 bit), as follows

If Load
	Alias L0 Byte_2
	Alias L1 Byte_1
	Alias L2 Byte_0
	Alias P0 Total
	Alias L4 Remainder
End

If M0 == E0
	Mat Total = M1 * $128
	Mat Total = Total + M2
	Mat Total = Total * $100
	Mat Total = Total / $1639 # Scale 16383 / 999 = 16.39

	Mat Byte_2 = Total / $100
	Mat Remainder = Total % $100

	Mat Byte_1 = Remainder / $10
	Mat Byte_0 = Remainder % $10

	Snd F0 58 58 Byte_2 Byte_1 Byte_0 F7 # Display result
End

This gets us bang on 16383 = 999

Last Edit: Jun 18, 2024 1:57:59 GMT by redheronmusic

mo13
Oracle

Posts: 146

Convert + scale Pitch Bend to 3 CCs Jun 18, 2024 8:24:15 GMT

Quote

Post by mo13 on Jun 18, 2024 8:24:15 GMT

Thank you for the input but it's partialy what i've ment.

The receiving device is expecting 3 CCS which will be setting the BPM (from 1 to 999) 1st CC representing hunders, 2nd tenth, 3rd ones.

to clear up the logic for you, the I/O should be as follow:

IN > OUT

EF 01 00 = BF $125 Byte_2 (Aka 00)
BF $126 Byte_1 (00)
BF $124 Byte_0 (01)

EF 02 00 = BF $125 Byte_2 (00)
BF $126 Byte_1 (00)
BF $127 Byte_0 (02)

EF 03 00 = BF $125 Byte_2 (00)
BF $126 Byte_1 (00)
BF $127 Byte_0 (03)

# SET BPM from 1 to 3

# here everyhing inbetween

the last BPM would for instance be

EF 7E 7F = BF $125 Byte_2 (Aka 09)
BF $126 Byte_1 (09)
BF $127 Byte_0 (09)

SET BPM to 999

#

Edit: this is as far as I've come but the range it still way off as it keeps looping few times through out 16383 PB data points:

# Convert Pitch Bend on Ch.16 to 3 CCs (125, 126, 127)
# representing BPM values (1-999)

IF LOAD
  Alias L0 Byte_2
  Alias L1 Byte_1
  Alias L2 Byte_0
  Alias P0 Total
  Alias L4 Remainder
  
  # Initialize previous values to track changes
  Alias K0 Prev_Byte_2
  Alias K1 Prev_Byte_1
  Alias K2 Prev_Byte_0
  
  ASS Prev_Byte_2 = 0
  ASS Prev_Byte_1 = 0
  ASS Prev_Byte_0 = 0
END

IF M0 == EF
  Mat Total = M1 * $128
  Mat Total = Total + M2
  Mat Total = Total * $100
  Mat Total = Total / $1639 # Scale 16383 / 999 = 16.39
  
  Mat Byte_2 = Total / $100
  Mat Remainder = Total % $100
  
  Mat Byte_1 = Remainder / $10
  Mat Byte_0 = Remainder % $10
  
  # Send the CC messages only if the value has changed
  IF Byte_2 != Prev_Byte_2
    Snd BF $125 Byte_2
    ASS Prev_Byte_2 = Byte_2
  END
  
  IF Byte_1 != Prev_Byte_1
    Snd BF $126 Byte_1
    ASS Prev_Byte_1 = Byte_1
  END
  
  IF Byte_0 != Prev_Byte_0
    Snd BF $127 Byte_0
    ASS Prev_Byte_0 = Byte_0
  END
End

Block

Last Edit: Jun 18, 2024 9:25:34 GMT by mo13

redheronmusic
Oracle

Posts: 78

Convert + scale Pitch Bend to 3 CCs Jun 18, 2024 11:29:26 GMT

Quote

Post by redheronmusic on Jun 18, 2024 11:29:26 GMT

I am not seeing the problem. In my test, the code counts up from

0 = 0 0 0
to 16383 = 9 9 9

Checking a few intermediate values:
EF 42 42 (8514d) = 5 1 9
EF 50 50 (10320d) = 6 2 9
EF 71 71 (14577d) = 8 8 9

Put the debug line back in to watch the raw values count up: Snd F0 58 58 Byte_2 Byte_1 Byte_0 F7 # Display result

Last Edit: Jun 18, 2024 11:29:46 GMT by redheronmusic